feat: Start using moko for i18n

i18n/build.gradle.kts

@@ -0,0 +1,49 @@
+plugins {
+    kotlin("multiplatform")
+    id("com.android.library")
+    id("dev.icerock.mobile.multiplatform-resources")
+}
+
+kotlin {
+    androidTarget()
+
+    applyDefaultHierarchyTemplate()
+
+    sourceSets {
+        val commonMain by getting {
+            dependencies {
+                api(libs.moko.resources)
+            }
+        }
+        val androidMain by getting {
+            dependsOn(commonMain)
+        }
+    }
+}
+
+android {
+    namespace = "yokai.i18n"
+
+    sourceSets {
+        named("main") {
+            res.srcDir("src/commonMain/moko-resources")
+        }
+    }
+}
+
+multiplatformResources {
+    resourcesPackage.set("yokai.i18n")
+}
+
+tasks {
+    val localesConfigTask = registerLocalesConfigTask(project)
+    preBuild {
+        dependsOn(localesConfigTask)
+    }
+
+    withType<org.jetbrains.kotlin.gradle.tasks.KotlinCompile> {
+        kotlinOptions.freeCompilerArgs += listOf(
+            "-Xexpect-actual-classes",
+        )
+    }
+}